powerpc: Add A2 cpu support

Add the cputable entry, regs and setup & restore entries for
the PowerPC A2 core.

Signed-off-by: Benjamin Herrenschmidt <benh@kernel.crashing.org>
Signed-off-by: Michael Ellerman <michael@ellerman.id.au>
Signed-off-by: Benjamin Herrenschmidt <benh@kernel.crashing.org>

3 files changed, 138 insertions, 2 deletions

diff --git a/arch/powerpc/kernel/Makefile b/arch/powerpc/kernel/Makefile
index 0fd6273bb8a9..058bc8bac488 100644
--- a/arch/powerpc/kernel/Makefile
+++ b/arch/powerpc/kernel/Makefile
@@ -41,6 +41,7 @@ obj-$(CONFIG_PPC_BOOK3S_64)	+= cpu_setup_ppc970.o cpu_setup_pa6t.o
 obj-$(CONFIG_PPC_BOOK3S_64)     += cpu_setup_power7.o
 obj64-$(CONFIG_RELOCATABLE)     += reloc_64.o
 obj-$(CONFIG_PPC_BOOK3E_64)     += exceptions-64e.o idle_book3e.o
+obj-$(CONFIG_PPC_A2)            += cpu_setup_a2.o
 obj-$(CONFIG_PPC64)             += vdso64/
 obj-$(CONFIG_ALTIVEC)           += vecemu.o
 obj-$(CONFIG_PPC_970_NAP)       += idle_power4.o
diff --git a/arch/powerpc/kernel/cpu_setup_a2.S b/arch/powerpc/kernel/cpu_setup_a2.S
new file mode 100644
index 000000000000..7f818feaa7a5
--- /dev/null
+++ b/arch/powerpc/kernel/cpu_setup_a2.S
@@ -0,0 +1,114 @@
+/*
+ *  A2 specific assembly support code
+ *
+ *  Copyright 2009 Ben Herrenschmidt, IBM Corp.
+ *
+ *  This program is free software; you can redistribute it and/or
+ *  modify it under the terms of the GNU General Public License
+ *  as published by the Free Software Foundation; either version
+ *  2 of the License, or (at your option) any later version.
+ */
+
+#include <asm/asm-offsets.h>
+#include <asm/ppc_asm.h>
+#include <asm/ppc-opcode.h>
+#include <asm/processor.h>
+#include <asm/reg_a2.h>
+#include <asm/reg.h>
+#include <asm/thread_info.h>
+
+/*
+ * Disable thdid and class fields in ERATs to bump PID to full 14 bits capacity.
+ * This also prevents external LPID accesses but that isn't a problem when not a
+ * guest. Under PV, this setting will be ignored and MMUCR will return the right
+ * number of PID bits we can use.
+ */
+#define MMUCR1_EXTEND_PID \
+        (MMUCR1_ICTID | MMUCR1_ITTID | MMUCR1_DCTID | \
+         MMUCR1_DTTID | MMUCR1_DCCD)
+
+/*
+ * Use extended PIDs if enabled.
+ * Don't clear the ERATs on context sync events and enable I & D LRU.
+ * Enable ERAT back invalidate when tlbwe overwrites an entry.
+ */
+#define INITIAL_MMUCR1 \
+        (MMUCR1_EXTEND_PID | MMUCR1_CSINV_NEVER | MMUCR1_IRRE | \
+         MMUCR1_DRRE | MMUCR1_TLBWE_BINV)
+
+_GLOBAL(__setup_cpu_a2)
+        /* Some of these are actually thread local and some are
+         * core local but doing it always won't hurt
+         */
+
+#ifdef CONFIG_PPC_WSP_COPRO
+        /* Make sure ACOP starts out as zero */
+        li      r3,0
+        mtspr   SPRN_ACOP,r3
+
+        /* Enable icswx instruction */
+        mfspr   r3,SPRN_A2_CCR2
+        ori     r3,r3,A2_CCR2_ENABLE_ICSWX
+        mtspr   SPRN_A2_CCR2,r3
+
+        /* Unmask all CTs in HACOP */
+        li      r3,-1
+        mtspr   SPRN_HACOP,r3
+#endif /* CONFIG_PPC_WSP_COPRO */
+
+        /* Enable doorbell */
+        mfspr   r3,SPRN_A2_CCR2
+        oris     r3,r3,A2_CCR2_ENABLE_PC@h
+        mtspr   SPRN_A2_CCR2,r3
+        isync
+
+        /* Setup CCR0 to disable power saving for now as it's busted
+         * in the current implementations. Setup CCR1 to wake on
+         * interrupts normally (we write the default value but who
+         * knows what FW may have clobbered...)
+         */
+        li      r3,0
+        mtspr   SPRN_A2_CCR0, r3
+        LOAD_REG_IMMEDIATE(r3,0x0f0f0f0f)
+        mtspr   SPRN_A2_CCR1, r3
+
+        /* Initialise MMUCR1 */
+        lis     r3,INITIAL_MMUCR1@h
+        ori     r3,r3,INITIAL_MMUCR1@l
+        mtspr   SPRN_MMUCR1,r3
+
+        /* Set MMUCR2 to enable 4K, 64K, 1M, 16M and 1G pages */
+        LOAD_REG_IMMEDIATE(r3, 0x000a7531)
+        mtspr   SPRN_MMUCR2,r3
+
+        /* Set MMUCR3 to write all thids bit to the TLB */
+        LOAD_REG_IMMEDIATE(r3, 0x0000000f)
+        mtspr   SPRN_MMUCR3,r3
+
+        /* Don't do ERAT stuff if running guest mode */
+        mfmsr   r3
+        andis.  r0,r3,MSR_GS@h
+        bne     1f
+
+        /* Now set the I-ERAT watermark to 15 */
+        lis     r4,(MMUCR0_TLBSEL_I|MMUCR0_ECL)@h
+        mtspr   SPRN_MMUCR0, r4
+        li      r4,A2_IERAT_SIZE-1
+        PPC_ERATWE(r4,r4,3)
+
+        /* Now set the D-ERAT watermark to 31 */
+        lis     r4,(MMUCR0_TLBSEL_D|MMUCR0_ECL)@h
+        mtspr   SPRN_MMUCR0, r4
+        li      r4,A2_DERAT_SIZE-1
+        PPC_ERATWE(r4,r4,3)
+
+        /* And invalidate the beast just in case. That won't get rid of
+         * a bolted entry though it will be in LRU and so will go away eventually
+         * but let's not bother for now
+         */
+        PPC_ERATILX(0,0,0)
+1:
+        blr
+
+_GLOBAL(__restore_cpu_a2)
+        b       __setup_cpu_a2
diff --git a/arch/powerpc/kernel/cputable.c b/arch/powerpc/kernel/cputable.c
index b65b4908d3c7..3d7b65ad4962 100644
--- a/arch/powerpc/kernel/cputable.c
+++ b/arch/powerpc/kernel/cputable.c
@@ -62,10 +62,12 @@ extern void __setup_cpu_745x(unsigned long offset, struct cpu_spec* spec);
 extern void __setup_cpu_ppc970(unsigned long offset, struct cpu_spec* spec);
 extern void __setup_cpu_ppc970MP(unsigned long offset, struct cpu_spec* spec);
 extern void __setup_cpu_pa6t(unsigned long offset, struct cpu_spec* spec);
+extern void __setup_cpu_a2(unsigned long offset, struct cpu_spec* spec);
 extern void __restore_cpu_pa6t(void);
 extern void __restore_cpu_ppc970(void);
 extern void __setup_cpu_power7(unsigned long offset, struct cpu_spec* spec);
 extern void __restore_cpu_power7(void);
+extern void __restore_cpu_a2(void);
 #endif /* CONFIG_PPC64 */
 #if defined(CONFIG_E500)
 extern void __setup_cpu_e5500(unsigned long offset, struct cpu_spec* spec);
@@ -2011,7 +2013,26 @@ static struct cpu_spec __initdata cpu_specs[] = {
 #endif /* CONFIG_PPC32 */
 #endif /* CONFIG_E500 */
 
-#ifdef CONFIG_PPC_BOOK3E_64
+#ifdef CONFIG_PPC_A2
+        {       /* Standard A2 (>= DD2) + FPU core */
+                .pvr_mask               = 0xffff0000,
+                .pvr_value              = 0x00480000,
+                .cpu_name               = "A2 (>= DD2)",
+                .cpu_features           = CPU_FTRS_A2,
+                .cpu_user_features      = COMMON_USER_PPC64,
+                .mmu_features           = MMU_FTR_TYPE_3E | MMU_FTR_USE_TLBILX |
+                                          MMU_FTR_USE_TLBIVAX_BCAST |
+                                          MMU_FTR_LOCK_BCAST_INVAL |
+                                          MMU_FTR_USE_TLBRSRV |
+                                          MMU_FTR_USE_PAIRED_MAS,
+                .icache_bsize           = 64,
+                .dcache_bsize           = 64,
+                .num_pmcs               = 0,
+                .cpu_setup              = __setup_cpu_a2,
+                .cpu_restore            = __restore_cpu_a2,
+                .machine_check          = machine_check_generic,
+                .platform               = "ppca2",
+        },
         {       /* This is a default entry to get going, to be replaced by
                  * a real one at some stage
                  */
@@ -2032,7 +2053,7 @@ static struct cpu_spec __initdata cpu_specs[] = {
                 .machine_check          = machine_check_generic,
                 .platform               = "power6",
         },
-#endif
+#endif /* CONFIG_PPC_A2 */
 };
 
 static struct cpu_spec the_cpu_spec;