2 files changed, 215 insertions, 0 deletions

diff --git a/arch/cris/kernel/asm-offsets.c b/arch/cris/kernel/asm-offsets.c
new file mode 100644
index 000000000000..ddd6fbbe75de
--- /dev/null
+++ b/arch/cris/kernel/asm-offsets.c
@@ -0,0 +1,64 @@
+#include <linux/sched.h>
+#include <asm/thread_info.h>
+#include <linux/autoconf.h>
+
+/*
+ * Generate definitions needed by assembly language modules.
+ * This code generates raw asm output which is post-processed to extract
+ * and format the required data.
+ */
+
+#define DEFINE(sym, val) \
+        asm volatile("\n->" #sym " %0 " #val : : "i" (val))
+
+#define BLANK() asm volatile("\n->" : : )
+
+#if !defined(CONFIG_ETRAX_ARCH_V10) && !defined(CONFIG_ETRAX_ARCH_V32)
+#error One of ARCH v10 and ARCH v32 must be true!
+#endif
+
+int main(void)
+{
+#define ENTRY(entry) DEFINE(PT_ ## entry, offsetof(struct pt_regs, entry))
+        ENTRY(orig_r10);
+        ENTRY(r13);
+        ENTRY(r12);
+        ENTRY(r11);
+        ENTRY(r10);
+        ENTRY(r9);
+#ifdef CONFIG_ETRAX_ARCH_V32
+        ENTRY(acr);
+        ENTRY(srs);
+#endif
+        ENTRY(mof);
+#ifdef CONFIG_ETRAX_ARCH_V10
+        ENTRY(dccr);
+#else
+        ENTRY(ccs);
+#endif
+        ENTRY(srp);
+        BLANK();
+#undef ENTRY
+#define ENTRY(entry) DEFINE(TI_ ## entry, offsetof(struct thread_info, entry))
+        ENTRY(task);
+        ENTRY(flags);
+        ENTRY(preempt_count);
+        BLANK();
+#undef ENTRY
+#define ENTRY(entry) DEFINE(THREAD_ ## entry, offsetof(struct thread_struct, entry))
+        ENTRY(ksp);
+        ENTRY(usp);
+#ifdef CONFIG_ETRAX_ARCH_V10
+        ENTRY(dccr);
+#else
+        ENTRY(ccs);
+#endif
+        BLANK();
+#undef ENTRY
+#define ENTRY(entry) DEFINE(TASK_ ## entry, offsetof(struct task_struct, entry))
+        ENTRY(pid);
+        BLANK();
+        DEFINE(LCLONE_VM, CLONE_VM);
+        DEFINE(LCLONE_UNTRACED, CLONE_UNTRACED);
+        return 0;
+}
diff --git a/arch/cris/kernel/vmlinux.lds.S b/arch/cris/kernel/vmlinux.lds.S
new file mode 100644
index 000000000000..0d2adfc794d4
--- /dev/null
+++ b/arch/cris/kernel/vmlinux.lds.S
@@ -0,0 +1,151 @@
+/* ld script to make the Linux/CRIS kernel
+ * Authors: Bjorn Wesen (bjornw@axis.com)
+ *
+ * It is VERY DANGEROUS to fiddle around with the symbols in this
+ * script. It is for example quite vital that all generated sections
+ * that are used are actually named here, otherwise the linker will
+ * put them at the end, where the init stuff is which is FREED after
+ * the kernel has booted.
+ */
+
+#include <linux/autoconf.h>
+#include <asm-generic/vmlinux.lds.h>
+#include <asm/page.h>
+
+#ifdef CONFIG_ETRAX_VMEM_SIZE
+#define __CONFIG_ETRAX_VMEM_SIZE CONFIG_ETRAX_VMEM_SIZE
+#else
+#define __CONFIG_ETRAX_VMEM_SIZE 0
+#endif
+
+
+jiffies = jiffies_64;
+SECTIONS
+{
+        . = DRAM_VIRTUAL_BASE;
+        dram_start = .;
+#ifdef CONFIG_ETRAX_ARCH_V10
+        ibr_start = .;
+#else
+        ebp_start = .;
+        /* The boot section is only necessary until the VCS top */
+        /* level testbench includes both flash and DRAM. */
+        .boot : { *(.boot) }
+#endif
+
+        /* see head.S and pages reserved at the start */
+        . = DRAM_VIRTUAL_BASE + 0x4000;
+
+        _text = .;                      /* Text and read-only data. */
+        text_start = .;                 /* Lots of aliases. */
+        _stext = .;
+        __stext = .;
+        .text : {
+                TEXT_TEXT
+                SCHED_TEXT
+                LOCK_TEXT
+                *(.fixup)
+                *(.text.__*)
+        }
+
+        _etext = . ;                    /* End of text section. */
+        __etext = .;
+
+        . = ALIGN(4);                   /* Exception table. */
+        __start___ex_table = .;
+        __ex_table : { *(__ex_table) }
+        __stop___ex_table = .;
+
+        RODATA
+
+        . = ALIGN (4);
+        ___data_start = . ;
+        __Sdata = . ;
+        .data : {                       /* Data */
+                DATA_DATA
+        }
+        __edata = . ;                   /* End of data section. */
+        _edata = . ;
+
+        . = ALIGN(PAGE_SIZE);   /* init_task and stack, must be aligned. */
+        .data.init_task : { *(.data.init_task) }
+
+        . = ALIGN(PAGE_SIZE);           /* Init code and data. */
+        __init_begin = .;
+        .init.text : {
+                   _sinittext = .;
+                   INIT_TEXT
+                   _einittext = .;
+        }
+        .init.data : { INIT_DATA }
+        . = ALIGN(16);
+        __setup_start = .;
+        .init.setup : { *(.init.setup) }
+        __setup_end = .;
+#ifdef CONFIG_ETRAX_ARCH_V32
+        __start___param = .;
+        __param : { *(__param) }
+        __stop___param = .;
+#endif
+        .initcall.init : {
+                __initcall_start = .;
+                INITCALLS
+                __initcall_end = .;
+        }
+
+        .con_initcall.init : {
+                __con_initcall_start = .;
+                *(.con_initcall.init)
+                __con_initcall_end = .;
+        }
+        SECURITY_INIT
+
+#ifdef CONFIG_ETRAX_ARCH_V10
+#ifdef CONFIG_BLK_DEV_INITRD
+        .init.ramfs : {
+                __initramfs_start = .;
+                *(.init.ramfs)
+                __initramfs_end = .;
+        }
+#endif
+#endif
+        __vmlinux_end = .;              /* Last address of the physical file. */
+#ifdef CONFIG_ETRAX_ARCH_V32
+        PERCPU(PAGE_SIZE)
+
+        .init.ramfs : {
+                __initramfs_start = .;
+                *(.init.ramfs)
+                __initramfs_end = .;
+        }
+#endif
+
+        /*
+         * We fill to the next page, so we can discard all init
+         * pages without needing to consider what payload might be
+         * appended to the kernel image.
+         */
+        . = ALIGN(PAGE_SIZE);
+
+        __init_end = .;
+
+        __data_end = . ;                /* Move to _edata ? */
+        __bss_start = .;                /* BSS. */
+        .bss : {
+                *(COMMON)
+                *(.bss)
+        }
+
+        . =  ALIGN (0x20);
+        _end = .;
+        __end = .;
+
+        /* Sections to be discarded */
+        /DISCARD/ : {
+                EXIT_TEXT
+                EXIT_DATA
+                *(.exitcall.exit)
+        }
+
+        dram_end = dram_start + (CONFIG_ETRAX_DRAM_SIZE - __CONFIG_ETRAX_VMEM_SIZE)*1024*1024;
+}