Merge branch 'x86/for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git/tip/linux-2.6-tip

* 'x86/for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git/tip/linux-2.6-tip: (821 commits)
  x86: make 64bit hpet_set_mapping to use ioremap too, v2
  x86: get x86_phys_bits early
  x86: max_low_pfn_mapped fix #4
  x86: change _node_to_cpumask_ptr to return const ptr
  x86: I/O APIC: remove an IRQ2-mask hack
  x86: fix numaq_tsc_disable calling
  x86, e820: remove end_user_pfn
  x86: max_low_pfn_mapped fix, #3
  x86: max_low_pfn_mapped fix, #2
  x86: max_low_pfn_mapped fix, #1
  x86_64: fix delayed signals
  x86: remove conflicting nx6325 and nx6125 quirks
  x86: Recover timer_ack lost in the merge of the NMI watchdog
  x86: I/O APIC: Never configure IRQ2
  x86: L-APIC: Always fully configure IRQ0
  x86: L-APIC: Set IRQ0 as edge-triggered
  x86: merge dwarf2 headers
  x86: use AS_CFI instead of UNWIND_INFO
  x86: use ignore macro instead of hash comment
  x86: use matching CFI_ENDPROC
  ...

1 files changed, 104 insertions, 0 deletions

diff --git a/arch/x86/lib/getuser.S b/arch/x86/lib/getuser.S
new file mode 100644
index 000000000000..ad374003742f
--- /dev/null
+++ b/arch/x86/lib/getuser.S
@@ -0,0 +1,104 @@
+/*
+ * __get_user functions.
+ *
+ * (C) Copyright 1998 Linus Torvalds
+ * (C) Copyright 2005 Andi Kleen
+ * (C) Copyright 2008 Glauber Costa
+ *
+ * These functions have a non-standard call interface
+ * to make them more efficient, especially as they
+ * return an error value in addition to the "real"
+ * return value.
+ */
+
+/*
+ * __get_user_X
+ *
+ * Inputs:      %[r|e]ax contains the address.
+ *              The register is modified, but all changes are undone
+ *              before returning because the C code doesn't know about it.
+ *
+ * Outputs:     %[r|e]ax is error code (0 or -EFAULT)
+ *              %[r|e]dx contains zero-extended value
+ *
+ *
+ * These functions should not modify any other registers,
+ * as they get called from within inline assembly.
+ */
+
+#include <linux/linkage.h>
+#include <asm/dwarf2.h>
+#include <asm/page.h>
+#include <asm/errno.h>
+#include <asm/asm-offsets.h>
+#include <asm/thread_info.h>
+#include <asm/asm.h>
+
+        .text
+ENTRY(__get_user_1)
+        CFI_STARTPROC
+        GET_THREAD_INFO(%_ASM_DX)
+        cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
+        jae bad_get_user
+1:      movzb (%_ASM_AX),%edx
+        xor %eax,%eax
+        ret
+        CFI_ENDPROC
+ENDPROC(__get_user_1)
+
+ENTRY(__get_user_2)
+        CFI_STARTPROC
+        add $1,%_ASM_AX
+        jc bad_get_user
+        GET_THREAD_INFO(%_ASM_DX)
+        cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
+        jae bad_get_user
+2:      movzwl -1(%_ASM_AX),%edx
+        xor %eax,%eax
+        ret
+        CFI_ENDPROC
+ENDPROC(__get_user_2)
+
+ENTRY(__get_user_4)
+        CFI_STARTPROC
+        add $3,%_ASM_AX
+        jc bad_get_user
+        GET_THREAD_INFO(%_ASM_DX)
+        cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
+        jae bad_get_user
+3:      mov -3(%_ASM_AX),%edx
+        xor %eax,%eax
+        ret
+        CFI_ENDPROC
+ENDPROC(__get_user_4)
+
+#ifdef CONFIG_X86_64
+ENTRY(__get_user_8)
+        CFI_STARTPROC
+        add $7,%_ASM_AX
+        jc bad_get_user
+        GET_THREAD_INFO(%_ASM_DX)
+        cmp TI_addr_limit(%_ASM_DX),%_ASM_AX
+        jae     bad_get_user
+4:      movq -7(%_ASM_AX),%_ASM_DX
+        xor %eax,%eax
+        ret
+        CFI_ENDPROC
+ENDPROC(__get_user_8)
+#endif
+
+bad_get_user:
+        CFI_STARTPROC
+        xor %edx,%edx
+        mov $(-EFAULT),%_ASM_AX
+        ret
+        CFI_ENDPROC
+END(bad_get_user)
+
+.section __ex_table,"a"
+        _ASM_PTR 1b,bad_get_user
+        _ASM_PTR 2b,bad_get_user
+        _ASM_PTR 3b,bad_get_user
+#ifdef CONFIG_X86_64
+        _ASM_PTR 4b,bad_get_user
+#endif