sparc: prepare lib/ for unification

Identical named files renamed to <name>_32.S
Refactored Makefile to prepare for unification.

Linking order was altered slightly - but this is a lib.a file so
it should not matter.

Signed-off-by: Sam Ravnborg <sam@ravnborg.org>
Signed-off-by: David S. Miller <davem@davemloft.net>

1 files changed, 47 insertions, 0 deletions

diff --git a/arch/sparc/lib/strncpy_from_user_32.S b/arch/sparc/lib/strncpy_from_user_32.S
new file mode 100644
index 000000000000..d77198976a66
--- /dev/null
+++ b/arch/sparc/lib/strncpy_from_user_32.S
@@ -0,0 +1,47 @@
+/* strncpy_from_user.S: Sparc strncpy from userspace.
+ *
+ *  Copyright(C) 1996 David S. Miller
+ */
+
+#include <asm/ptrace.h>
+#include <asm/errno.h>
+
+        .text
+        .align  4
+
+        /* Must return:
+         *
+         * -EFAULT              for an exception
+         * count                if we hit the buffer limit
+         * bytes copied         if we hit a null byte
+         */
+
+        .globl  __strncpy_from_user
+__strncpy_from_user:
+        /* %o0=dest, %o1=src, %o2=count */
+        mov     %o2, %o3
+1:
+        subcc   %o2, 1, %o2
+        bneg    2f
+         nop
+10:
+        ldub    [%o1], %o4
+        add     %o0, 1, %o0
+        cmp     %o4, 0
+        add     %o1, 1, %o1
+        bne     1b
+         stb    %o4, [%o0 - 1]
+2:
+        add     %o2, 1, %o0
+        retl
+         sub    %o3, %o0, %o0
+
+        .section .fixup,#alloc,#execinstr
+        .align  4
+4:
+        retl
+         mov    -EFAULT, %o0
+
+        .section __ex_table,#alloc
+        .align  4
+        .word   10b, 4b