Merge master.kernel.org:/home/rmk/linux-2.6-arm

* master.kernel.org:/home/rmk/linux-2.6-arm: (26 commits)
  [ARM] pxa: fix 1c104e0e4f6ab396960c058e95e18bdedcac945b
  [ARM] serial: s3c2410: platform_get_irq() may return signed unnoticed
  [ARM] am79c961a: platform_get_irq() may return signed unnoticed
  [ARM] Feroceon: Feroceon-specific WA-cache compatible {copy,clear}_user_page()
  [ARM] Feroceon: fix function alignment in proc-feroceon.S
  [ARM] Orion: catch a couple more alternative spellings of PCIe
  [ARM] Orion: fix orion-ehci platform resource end addresses
  [ARM] Orion: fix ->map_irq() PCIe bus number check
  [ARM] Orion: fix ioremap() optimization
  [ARM] feroceon: remove CONFIG_CPU_CACHE_ROUND_ROBIN check
  [ARM] feroceon: remove CONFIG_CPU_DCACHE_WRITETHROUGH check
  kprobes/arm: fix decoding of arithmetic immediate instructions
  kprobes/arm: fix cache flush address for instruction stub
  [ARM] 5022/1: Race in ARM MMCI PL18x driver, V2
  [ARM] 5021/1: at91: buildfix for sam9263 + PM
  [ARM] 5018/1: RealView: Fix the ARM11MPCore Oprofile compilation
  [ARM] 5016/1: AT91: typo in mci configuration for at91cap at91sam9263
  [ARM] 5017/1: pxa3xx: Report unsupported wakeup sources in pxa3xx_set_wake()
  [ARM] 5020/1: magician: remove __devinit marker from pasic3_leds_info
  [ARM] 5014/1: Cleanup reset state before entering suspend or resetting.
  ...

1 files changed, 95 insertions, 0 deletions

diff --git a/arch/arm/mm/copypage-feroceon.S b/arch/arm/mm/copypage-feroceon.S
new file mode 100644
index 000000000000..7eb0d320d240
--- /dev/null
+++ b/arch/arm/mm/copypage-feroceon.S
@@ -0,0 +1,95 @@
+/*
+ *  linux/arch/arm/lib/copypage-feroceon.S
+ *
+ *  Copyright (C) 2008 Marvell Semiconductors
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 2 as
+ * published by the Free Software Foundation.
+ *
+ * This handles copy_user_page and clear_user_page on Feroceon
+ * more optimally than the generic implementations.
+ */
+#include <linux/linkage.h>
+#include <linux/init.h>
+#include <asm/asm-offsets.h>
+
+        .text
+        .align  5
+
+ENTRY(feroceon_copy_user_page)
+        stmfd   sp!, {r4-r9, lr}
+        mov     ip, #PAGE_SZ
+1:      mov     lr, r1
+        ldmia   r1!, {r2 - r9}
+        pld     [lr, #32]
+        pld     [lr, #64]
+        pld     [lr, #96]
+        pld     [lr, #128]
+        pld     [lr, #160]
+        pld     [lr, #192]
+        pld     [lr, #224]
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        ldmia   r1!, {r2 - r9}
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        stmia   r0, {r2 - r9}
+        subs    ip, ip, #(32 * 8)
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        bne     1b
+        mcr     p15, 0, ip, c7, c10, 4          @ drain WB
+        ldmfd   sp!, {r4-r9, pc}
+
+        .align  5
+
+ENTRY(feroceon_clear_user_page)
+        stmfd   sp!, {r4-r7, lr}
+        mov     r1, #PAGE_SZ/32
+        mov     r2, #0
+        mov     r3, #0
+        mov     r4, #0
+        mov     r5, #0
+        mov     r6, #0
+        mov     r7, #0
+        mov     ip, #0
+        mov     lr, #0
+1:      stmia   r0, {r2-r7, ip, lr}
+        subs    r1, r1, #1
+        mcr     p15, 0, r0, c7, c14, 1          @ clean and invalidate D line
+        add     r0, r0, #32
+        bne     1b
+        mcr     p15, 0, r1, c7, c10, 4          @ drain WB
+        ldmfd   sp!, {r4-r7, pc}
+
+        __INITDATA
+
+        .type   feroceon_user_fns, #object
+ENTRY(feroceon_user_fns)
+        .long   feroceon_clear_user_page
+        .long   feroceon_copy_user_page
+        .size   feroceon_user_fns, . - feroceon_user_fns