ARM: 8091/2: add get_user() support for 8 byte types

Recent contributions, including to DRM and binder, introduce 64-bit
values in their interfaces. A common motivation for this is to allow
the same ABI for 32- and 64-bit userspaces (and therefore also a shared
ABI for 32/64 hybrid userspaces). Anyhow, the developers would like to
avoid gotchas like having to use copy_from_user().

This feature is already implemented on x86-32 and the majority of other
32-bit architectures. The current list of get_user_8 hold out
architectures are: arm, avr32, blackfin, m32r, metag, microblaze,
mn10300, sh.

Credit:

    My name sits rather uneasily at the top of this patch. The v1 and
    v2 versions of the patch were written by Rob Clark and to produce v4
    I mostly copied code from Russell King and H. Peter Anvin. However I
    have mangled the patch sufficiently that *blame* is rightfully mine
    even if credit should more widely shared.

Changelog:

v5: updated to use the ret macro (requested by Russell King)
v4: remove an inlined add on big endian systems (spotted by Russell King),
    used __ARMEB__ rather than BIG_ENDIAN (to match rest of file),
    cleared r3 on EFAULT during __get_user_8.
v3: fix a couple of checkpatch issues
v2: pass correct size to check_uaccess, and better handling of narrowing
    double word read with __get_user_xb() (Russell King's suggestion)
v1: original

Signed-off-by: Rob Clark <robdclark@gmail.com>
Signed-off-by: Daniel Thompson <daniel.thompson@linaro.org>
Signed-off-by: Russell King <rmk+kernel@arm.linux.org.uk>

1 files changed, 36 insertions, 1 deletions

diff --git a/arch/arm/lib/getuser.S b/arch/arm/lib/getuser.S
index 0f958e3d8180..938600098b88 100644
--- a/arch/arm/lib/getuser.S
+++ b/arch/arm/lib/getuser.S
@@ -18,7 +18,7 @@
  * Inputs:      r0 contains the address
  *              r1 contains the address limit, which must be preserved
  * Outputs:     r0 is the error code
- *              r2 contains the zero-extended value
+ *              r2, r3 contains the zero-extended value
  *              lr corrupted
  *
  * No other registers must be altered.  (see <asm/uaccess.h>
@@ -66,15 +66,50 @@ ENTRY(__get_user_4)
         ret     lr
 ENDPROC(__get_user_4)
 
+ENTRY(__get_user_8)
+        check_uaccess r0, 8, r1, r2, __get_user_bad
+#ifdef CONFIG_THUMB2_KERNEL
+5: TUSER(ldr)   r2, [r0]
+6: TUSER(ldr)   r3, [r0, #4]
+#else
+5: TUSER(ldr)   r2, [r0], #4
+6: TUSER(ldr)   r3, [r0]
+#endif
+        mov     r0, #0
+        ret     lr
+ENDPROC(__get_user_8)
+
+#ifdef __ARMEB__
+ENTRY(__get_user_lo8)
+        check_uaccess r0, 8, r1, r2, __get_user_bad
+#ifdef CONFIG_CPU_USE_DOMAINS
+        add     r0, r0, #4
+7:      ldrt    r2, [r0]
+#else
+7:      ldr     r2, [r0, #4]
+#endif
+        mov     r0, #0
+        ret     lr
+ENDPROC(__get_user_lo8)
+#endif
+
+__get_user_bad8:
+        mov     r3, #0
 __get_user_bad:
         mov     r2, #0
         mov     r0, #-EFAULT
         ret     lr
 ENDPROC(__get_user_bad)
+ENDPROC(__get_user_bad8)
 
 .pushsection __ex_table, "a"
         .long   1b, __get_user_bad
         .long   2b, __get_user_bad
         .long   3b, __get_user_bad
         .long   4b, __get_user_bad
+        .long   5b, __get_user_bad8
+        .long   6b, __get_user_bad8
+#ifdef __ARMEB__
+        .long   7b, __get_user_bad
+#endif
 .popsection