3 files changed, 152 insertions, 0 deletions

diff --git a/arch/arm/lib/delay.S b/arch/arm/lib/delay.S
new file mode 100644
index 00000000000..3c9a05c8d20
--- /dev/null
+++ b/arch/arm/lib/delay.S
@@ -0,0 +1,69 @@
+/*
+ *  linux/arch/arm/lib/delay.S
+ *
+ *  Copyright (C) 1995, 1996 Russell King
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 2 as
+ * published by the Free Software Foundation.
+ */
+#include <linux/linkage.h>
+#include <asm/assembler.h>
+#include <asm/param.h>
+                .text
+
+.LC0:           .word   loops_per_jiffy
+.LC1:           .word   (2199023*HZ)>>11
+
+/*
+ * r0  <= 2000
+ * lpj <= 0x01ffffff (max. 3355 bogomips)
+ * HZ  <= 1000
+ */
+
+ENTRY(__udelay)
+                ldr     r2, .LC1
+                mul     r0, r2, r0
+ENTRY(__const_udelay)                           @ 0 <= r0 <= 0x7fffff06
+                mov     r1, #-1
+                ldr     r2, .LC0
+                ldr     r2, [r2]                @ max = 0x01ffffff
+                add     r0, r0, r1, lsr #32-14
+                mov     r0, r0, lsr #14         @ max = 0x0001ffff
+                add     r2, r2, r1, lsr #32-10
+                mov     r2, r2, lsr #10         @ max = 0x00007fff
+                mul     r0, r2, r0              @ max = 2^32-1
+                add     r0, r0, r1, lsr #32-6
+                movs    r0, r0, lsr #6
+                moveq   pc, lr
+
+/*
+ * loops = r0 * HZ * loops_per_jiffy / 1000000
+ *
+ * Oh, if only we had a cycle counter...
+ */
+
+@ Delay routine
+ENTRY(__delay)
+                subs    r0, r0, #1
+#if 0
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+                movls   pc, lr
+                subs    r0, r0, #1
+#endif
+                bhi     __delay
+                mov     pc, lr
+ENDPROC(__udelay)
+ENDPROC(__const_udelay)
+ENDPROC(__delay)
diff --git a/arch/arm/lib/strncpy_from_user.S b/arch/arm/lib/strncpy_from_user.S
new file mode 100644
index 00000000000..f202d7bd164
--- /dev/null
+++ b/arch/arm/lib/strncpy_from_user.S
@@ -0,0 +1,43 @@
+/*
+ *  linux/arch/arm/lib/strncpy_from_user.S
+ *
+ *  Copyright (C) 1995-2000 Russell King
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 2 as
+ * published by the Free Software Foundation.
+ */
+#include <linux/linkage.h>
+#include <asm/assembler.h>
+#include <asm/errno.h>
+
+        .text
+        .align  5
+
+/*
+ * Copy a string from user space to kernel space.
+ *  r0 = dst, r1 = src, r2 = byte length
+ * returns the number of characters copied (strlen of copied string),
+ *  -EFAULT on exception, or "len" if we fill the whole buffer
+ */
+ENTRY(__strncpy_from_user)
+        mov     ip, r1
+1:      subs    r2, r2, #1
+        ldrusr  r3, r1, 1, pl
+        bmi     2f
+        strb    r3, [r0], #1
+        teq     r3, #0
+        bne     1b
+        sub     r1, r1, #1      @ take NUL character out of count
+2:      sub     r0, r1, ip
+        mov     pc, lr
+ENDPROC(__strncpy_from_user)
+
+        .pushsection .fixup,"ax"
+        .align  0
+9001:   mov     r3, #0
+        strb    r3, [r0, #0]    @ null terminate
+        mov     r0, #-EFAULT
+        mov     pc, lr
+        .popsection
+
diff --git a/arch/arm/lib/strnlen_user.S b/arch/arm/lib/strnlen_user.S
new file mode 100644
index 00000000000..0ecbb459c4f
--- /dev/null
+++ b/arch/arm/lib/strnlen_user.S
@@ -0,0 +1,40 @@
+/*
+ *  linux/arch/arm/lib/strnlen_user.S
+ *
+ *  Copyright (C) 1995-2000 Russell King
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 2 as
+ * published by the Free Software Foundation.
+ */
+#include <linux/linkage.h>
+#include <asm/assembler.h>
+#include <asm/errno.h>
+
+        .text
+        .align  5
+
+/* Prototype: unsigned long __strnlen_user(const char *str, long n)
+ * Purpose  : get length of a string in user memory
+ * Params   : str - address of string in user memory
+ * Returns  : length of string *including terminator*
+ *            or zero on exception, or n + 1 if too long
+ */
+ENTRY(__strnlen_user)
+        mov     r2, r0
+1:
+        ldrusr  r3, r0, 1
+        teq     r3, #0
+        beq     2f
+        subs    r1, r1, #1
+        bne     1b
+        add     r0, r0, #1
+2:      sub     r0, r0, r2
+        mov     pc, lr
+ENDPROC(__strnlen_user)
+
+        .pushsection .fixup,"ax"
+        .align  0
+9001:   mov     r0, #0
+        mov     pc, lr
+        .popsection