Added missing tegra files.HEADmaster

3 files changed, 142 insertions, 0 deletions

diff --git a/arch/frv/kernel/init_task.c b/arch/frv/kernel/init_task.c
new file mode 100644
index 00000000000..3c3e0b336a9
--- /dev/null
+++ b/arch/frv/kernel/init_task.c
@@ -0,0 +1,32 @@
+#include <linux/mm.h>
+#include <linux/module.h>
+#include <linux/sched.h>
+#include <linux/init.h>
+#include <linux/init_task.h>
+#include <linux/fs.h>
+#include <linux/mqueue.h>
+
+#include <asm/uaccess.h>
+#include <asm/pgtable.h>
+
+
+static struct signal_struct init_signals = INIT_SIGNALS(init_signals);
+static struct sighand_struct init_sighand = INIT_SIGHAND(init_sighand);
+/*
+ * Initial thread structure.
+ *
+ * We need to make sure that this is THREAD_SIZE aligned due to the
+ * way process stacks are handled. This is done by having a special
+ * "init_task" linker map entry..
+ */
+union thread_union init_thread_union __init_task_data =
+        { INIT_THREAD_INFO(init_task) };
+
+/*
+ * Initial task structure.
+ *
+ * All other task structs will be allocated on slabs in fork.c
+ */
+struct task_struct init_task = INIT_TASK(init_task);
+
+EXPORT_SYMBOL(init_task);
diff --git a/arch/frv/kernel/kernel_execve.S b/arch/frv/kernel/kernel_execve.S
new file mode 100644
index 00000000000..9b074a16a05
--- /dev/null
+++ b/arch/frv/kernel/kernel_execve.S
@@ -0,0 +1,33 @@
+/* in-kernel program execution
+ *
+ * Copyright (C) 2006 Red Hat, Inc. All Rights Reserved.
+ * Written by David Howells (dhowells@redhat.com)
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * as published by the Free Software Foundation; either version
+ * 2 of the License, or (at your option) any later version.
+ */
+
+#include <linux/linkage.h>
+#include <asm/unistd.h>
+
+###############################################################################
+#
+# Do a system call from kernel instead of calling sys_execve so we end up with
+# proper pt_regs.
+#
+# int kernel_execve(const char *filename, char *const argv[], char *const envp[])
+#
+# On entry: GR8/GR9/GR10: arguments to function
+# On return: GR8: syscall return.
+#
+###############################################################################
+        .globl          kernel_execve
+        .type           kernel_execve,@function
+kernel_execve:
+        setlos          __NR_execve,gr7
+        tira            gr0,#0
+        bralr
+
+        .size           kernel_execve,.-kernel_execve
diff --git a/arch/frv/kernel/kernel_thread.S b/arch/frv/kernel/kernel_thread.S
new file mode 100644
index 00000000000..4531c830d20
--- /dev/null
+++ b/arch/frv/kernel/kernel_thread.S
@@ -0,0 +1,77 @@
+/* kernel_thread.S: kernel thread creation
+ *
+ * Copyright (C) 2003 Red Hat, Inc. All Rights Reserved.
+ * Written by David Howells (dhowells@redhat.com)
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * as published by the Free Software Foundation; either version
+ * 2 of the License, or (at your option) any later version.
+ */
+
+#include <linux/linkage.h>
+#include <asm/unistd.h>
+
+#define CLONE_VM        0x00000100      /* set if VM shared between processes */
+#define KERN_ERR        "<3>"
+
+        .section .rodata
+kernel_thread_emsg:
+        .asciz  KERN_ERR "failed to create kernel thread: error=%d\n"
+
+        .text
+        .balign         4
+
+###############################################################################
+#
+# Create a kernel thread
+#
+# int kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
+#
+###############################################################################
+        .globl          kernel_thread
+        .type           kernel_thread,@function
+kernel_thread:
+        or.p            gr8,gr0,gr4
+        or              gr9,gr0,gr5
+
+        # start by forking the current process, but with shared VM
+        setlos.p        #__NR_clone,gr7         ; syscall number
+        ori             gr10,#CLONE_VM,gr8      ; first syscall arg     [clone_flags]
+        sethi.p         #0xe4e4,gr9             ; second syscall arg    [newsp]
+        setlo           #0xe4e4,gr9
+        setlos.p        #0,gr10                 ; third syscall arg     [parent_tidptr]
+        setlos          #0,gr11                 ; fourth syscall arg    [child_tidptr]
+        tira            gr0,#0
+        setlos.p        #4095,gr7
+        andcc           gr8,gr8,gr0,icc0
+        addcc.p         gr8,gr7,gr0,icc1
+        bnelr           icc0,#2
+        bc              icc1,#0,kernel_thread_error
+
+        # now invoke the work function
+        or              gr5,gr0,gr8
+        calll           @(gr4,gr0)
+
+        # and finally exit the thread
+        setlos          #__NR_exit,gr7          ; syscall number
+        tira            gr0,#0
+
+kernel_thread_error:
+        subi            sp,#8,sp
+        movsg           lr,gr4
+        sti             gr8,@(sp,#0)
+        sti.p           gr4,@(sp,#4)
+
+        or              gr8,gr0,gr9
+        sethi.p         %hi(kernel_thread_emsg),gr8
+        setlo           %lo(kernel_thread_emsg),gr8
+
+        call            printk
+
+        ldi             @(sp,#4),gr4
+        ldi             @(sp,#0),gr8
+        subi            sp,#8,sp
+        jmpl            @(gr4,gr0)
+
+        .size           kernel_thread,.-kernel_thread