Merge branch 'ras-core-for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git/tip/tip

Pull RAS updates from Ingo Molnar:
 "Various RAS updates:

   - AMD MCE support updates for future CPUs, fixes and 'SMCA' (Scalable
     MCA) error decoding support (Aravind Gopalakrishnan)

   - x86 memcpy_mcsafe() support, to enable smart(er) hardware error
     recovery in NVDIMM drivers, based on an extension of the x86
     exception handling code.  (Tony Luck)"

* 'ras-core-for-linus' of git://git.kernel.org/pub/scm/linux/kernel/git/tip/tip:
  EDAC/sb_edac: Fix computation of channel address
  x86/mm, x86/mce: Add memcpy_mcsafe()
  x86/mce/AMD: Document some functionality
  x86/mce: Clarify comments regarding deferred error
  x86/mce/AMD: Fix logic to obtain block address
  x86/mce/AMD, EDAC: Enable error decoding of Scalable MCA errors
  x86/mce: Move MCx_CONFIG MSR definitions
  x86/mce: Check for faults tagged in EXTABLE_CLASS_FAULT exception table entries
  x86/mm: Expand the exception table logic to allow new handling options
  x86/mce/AMD: Set MCAX Enable bit
  x86/mce/AMD: Carve out threshold block preparation
  x86/mce/AMD: Fix LVT offset configuration for thresholding
  x86/mce/AMD: Reduce number of blocks scanned per bank
  x86/mce/AMD: Do not perform shared bank check for future processors
  x86/mce: Fix order of AMD MCE init function call

1 files changed, 117 insertions, 0 deletions

diff --git a/arch/x86/lib/memcpy_64.S b/arch/x86/lib/memcpy_64.S
index 16698bba87de..7d37641ada5b 100644
--- a/arch/x86/lib/memcpy_64.S
+++ b/arch/x86/lib/memcpy_64.S
@@ -177,3 +177,120 @@ ENTRY(memcpy_orig)
 .Lend:
         retq
 ENDPROC(memcpy_orig)
+
+#ifndef CONFIG_UML
+/*
+ * memcpy_mcsafe - memory copy with machine check exception handling
+ * Note that we only catch machine checks when reading the source addresses.
+ * Writes to target are posted and don't generate machine checks.
+ */
+ENTRY(memcpy_mcsafe)
+        cmpl $8, %edx
+        /* Less than 8 bytes? Go to byte copy loop */
+        jb .L_no_whole_words
+
+        /* Check for bad alignment of source */
+        testl $7, %esi
+        /* Already aligned */
+        jz .L_8byte_aligned
+
+        /* Copy one byte at a time until source is 8-byte aligned */
+        movl %esi, %ecx
+        andl $7, %ecx
+        subl $8, %ecx
+        negl %ecx
+        subl %ecx, %edx
+.L_copy_leading_bytes:
+        movb (%rsi), %al
+        movb %al, (%rdi)
+        incq %rsi
+        incq %rdi
+        decl %ecx
+        jnz .L_copy_leading_bytes
+
+.L_8byte_aligned:
+        /* Figure out how many whole cache lines (64-bytes) to copy */
+        movl %edx, %ecx
+        andl $63, %edx
+        shrl $6, %ecx
+        jz .L_no_whole_cache_lines
+
+        /* Loop copying whole cache lines */
+.L_cache_w0: movq (%rsi), %r8
+.L_cache_w1: movq 1*8(%rsi), %r9
+.L_cache_w2: movq 2*8(%rsi), %r10
+.L_cache_w3: movq 3*8(%rsi), %r11
+        movq %r8, (%rdi)
+        movq %r9, 1*8(%rdi)
+        movq %r10, 2*8(%rdi)
+        movq %r11, 3*8(%rdi)
+.L_cache_w4: movq 4*8(%rsi), %r8
+.L_cache_w5: movq 5*8(%rsi), %r9
+.L_cache_w6: movq 6*8(%rsi), %r10
+.L_cache_w7: movq 7*8(%rsi), %r11
+        movq %r8, 4*8(%rdi)
+        movq %r9, 5*8(%rdi)
+        movq %r10, 6*8(%rdi)
+        movq %r11, 7*8(%rdi)
+        leaq 64(%rsi), %rsi
+        leaq 64(%rdi), %rdi
+        decl %ecx
+        jnz .L_cache_w0
+
+        /* Are there any trailing 8-byte words? */
+.L_no_whole_cache_lines:
+        movl %edx, %ecx
+        andl $7, %edx
+        shrl $3, %ecx
+        jz .L_no_whole_words
+
+        /* Copy trailing words */
+.L_copy_trailing_words:
+        movq (%rsi), %r8
+        mov %r8, (%rdi)
+        leaq 8(%rsi), %rsi
+        leaq 8(%rdi), %rdi
+        decl %ecx
+        jnz .L_copy_trailing_words
+
+        /* Any trailing bytes? */
+.L_no_whole_words:
+        andl %edx, %edx
+        jz .L_done_memcpy_trap
+
+        /* Copy trailing bytes */
+        movl %edx, %ecx
+.L_copy_trailing_bytes:
+        movb (%rsi), %al
+        movb %al, (%rdi)
+        incq %rsi
+        incq %rdi
+        decl %ecx
+        jnz .L_copy_trailing_bytes
+
+        /* Copy successful. Return true */
+.L_done_memcpy_trap:
+        xorq %rax, %rax
+        ret
+ENDPROC(memcpy_mcsafe)
+
+        .section .fixup, "ax"
+        /* Return false for any failure */
+.L_memcpy_mcsafe_fail:
+        mov     $1, %rax
+        ret
+
+        .previous
+
+        _ASM_EXTABLE_FAULT(.L_copy_leading_bytes, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w0, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w1, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w3, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w3, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w4, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w5, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w6, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_cache_w7, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_copy_trailing_words, .L_memcpy_mcsafe_fail)
+        _ASM_EXTABLE_FAULT(.L_copy_trailing_bytes, .L_memcpy_mcsafe_fail)
+#endif