1 files changed, 72 insertions, 0 deletions

diff --git a/arch/x86/kernel/entry_32.S b/arch/x86/kernel/entry_32.S
index c778e4fa55a2..95e6bbe3665e 100644
--- a/arch/x86/kernel/entry_32.S
+++ b/arch/x86/kernel/entry_32.S
@@ -51,6 +51,7 @@
 #include <asm/percpu.h>
 #include <asm/dwarf2.h>
 #include <asm/processor-flags.h>
+#include <asm/ftrace.h>
 #include "irq_vectors.h"
 
 /*
@@ -1110,6 +1111,77 @@ ENDPROC(xen_failsafe_callback)
 
 #endif  /* CONFIG_XEN */
 
+#ifdef CONFIG_FTRACE
+#ifdef CONFIG_DYNAMIC_FTRACE
+
+ENTRY(mcount)
+        pushl %eax
+        pushl %ecx
+        pushl %edx
+        movl 0xc(%esp), %eax
+        subl $MCOUNT_INSN_SIZE, %eax
+
+.globl mcount_call
+mcount_call:
+        call ftrace_stub
+
+        popl %edx
+        popl %ecx
+        popl %eax
+
+        ret
+END(mcount)
+
+ENTRY(ftrace_caller)
+        pushl %eax
+        pushl %ecx
+        pushl %edx
+        movl 0xc(%esp), %eax
+        movl 0x4(%ebp), %edx
+        subl $MCOUNT_INSN_SIZE, %eax
+
+.globl ftrace_call
+ftrace_call:
+        call ftrace_stub
+
+        popl %edx
+        popl %ecx
+        popl %eax
+
+.globl ftrace_stub
+ftrace_stub:
+        ret
+END(ftrace_caller)
+
+#else /* ! CONFIG_DYNAMIC_FTRACE */
+
+ENTRY(mcount)
+        cmpl $ftrace_stub, ftrace_trace_function
+        jnz trace
+.globl ftrace_stub
+ftrace_stub:
+        ret
+
+        /* taken from glibc */
+trace:
+        pushl %eax
+        pushl %ecx
+        pushl %edx
+        movl 0xc(%esp), %eax
+        movl 0x4(%ebp), %edx
+        subl $MCOUNT_INSN_SIZE, %eax
+
+        call *ftrace_trace_function
+
+        popl %edx
+        popl %ecx
+        popl %eax
+
+        jmp ftrace_stub
+END(mcount)
+#endif /* CONFIG_DYNAMIC_FTRACE */
+#endif /* CONFIG_FTRACE */
+
 .section .rodata,"a"
 #include "syscall_table_32.S"