diff options
Diffstat (limited to 'arch/s390/kernel/relocate_kernel64.S')
| -rw-r--r-- | arch/s390/kernel/relocate_kernel64.S | 82 |
1 files changed, 82 insertions, 0 deletions
diff --git a/arch/s390/kernel/relocate_kernel64.S b/arch/s390/kernel/relocate_kernel64.S new file mode 100644 index 000000000000..96290cc4eb3c --- /dev/null +++ b/arch/s390/kernel/relocate_kernel64.S | |||
| @@ -0,0 +1,82 @@ | |||
| 1 | /* | ||
| 2 | * arch/s390/kernel/relocate_kernel64.S | ||
| 3 | * | ||
| 4 | * (C) Copyright IBM Corp. 2005 | ||
| 5 | * | ||
| 6 | * Author(s): Rolf Adelsberger <adelsberger@de.ibm.com> | ||
| 7 | * | ||
| 8 | */ | ||
| 9 | |||
| 10 | /* | ||
| 11 | * moves the new kernel to its destination... | ||
| 12 | * %r2 = pointer to first kimage_entry_t | ||
| 13 | * %r3 = start address - where to jump to after the job is done... | ||
| 14 | * | ||
| 15 | * %r5 will be used as temp. storage | ||
| 16 | * %r6 holds the destination address | ||
| 17 | * %r7 = PAGE_SIZE | ||
| 18 | * %r8 holds the source address | ||
| 19 | * %r9 = PAGE_SIZE | ||
| 20 | * | ||
| 21 | * 0xf000 is a page_mask | ||
| 22 | */ | ||
| 23 | |||
| 24 | .text | ||
| 25 | .globl relocate_kernel | ||
| 26 | relocate_kernel: | ||
| 27 | basr %r13,0 #base address | ||
| 28 | .base: | ||
| 29 | spx zero64-.base(%r13) #absolute addressing mode | ||
| 30 | stnsm sys_msk-.base(%r13),0xf8 #disable DAT and IRQ (external) | ||
| 31 | .top: | ||
| 32 | lghi %r7,4096 #load PAGE_SIZE in r7 | ||
| 33 | lghi %r9,4096 #load PAGE_SIZE in r9 | ||
| 34 | lg %r5,0(%r2) #read another word for indirection page | ||
| 35 | aghi %r2,8 #increment pointer | ||
| 36 | tml %r5,0x1 #is it a destination page? | ||
| 37 | je .indir_check #NO, goto "indir_check" | ||
| 38 | lgr %r6,%r5 #r6 = r5 | ||
| 39 | nill %r6,0xf000 #mask it out and... | ||
| 40 | j .top #...next iteration | ||
| 41 | .indir_check: | ||
| 42 | tml %r5,0x2 #is it a indirection page? | ||
| 43 | je .done_test #NO, goto "done_test" | ||
| 44 | nill %r5,0xf000 #YES, mask out, | ||
| 45 | lgr %r2,%r5 #move it into the right register, | ||
| 46 | j .top #and read next... | ||
| 47 | .done_test: | ||
| 48 | tml %r5,0x4 #is it the done indicator? | ||
| 49 | je .source_test #NO! Well, then it should be the source indicator... | ||
| 50 | j .done #ok, lets finish it here... | ||
| 51 | .source_test: | ||
| 52 | tml %r5,0x8 #it should be a source indicator... | ||
| 53 | je .top #NO, ignore it... | ||
| 54 | lgr %r8,%r5 #r8 = r5 | ||
| 55 | nill %r8,0xf000 #masking | ||
| 56 | 0: mvcle %r6,%r8,0x0 #copy PAGE_SIZE bytes from r8 to r6 - pad with 0 | ||
| 57 | jo 0b | ||
| 58 | j .top | ||
| 59 | .done: | ||
| 60 | sgr %r0,%r0 #clear register r0 | ||
| 61 | la %r4,load_psw-.base(%r13) #load psw-address into the register | ||
| 62 | o %r3,4(%r4) #or load address into psw | ||
| 63 | st %r3,4(%r4) | ||
| 64 | mvc 0(8,%r0),0(%r4) #copy psw to absolute address 0 | ||
| 65 | sam31 #31 bit mode | ||
| 66 | sr %r1,%r1 #erase register r1 | ||
| 67 | sr %r2,%r2 #erase register r2 | ||
| 68 | sigp %r1,%r2,0x12 #set cpuid to zero | ||
| 69 | lpsw 0 #hopefully start new kernel... | ||
| 70 | |||
| 71 | .align 8 | ||
| 72 | zero64: | ||
| 73 | .quad 0 | ||
| 74 | load_psw: | ||
| 75 | .long 0x00080000,0x80000000 | ||
| 76 | sys_msk: | ||
| 77 | .quad 0 | ||
| 78 | relocate_kernel_end: | ||
| 79 | .globl relocate_kernel_len | ||
| 80 | relocate_kernel_len: | ||
| 81 | .quad relocate_kernel_end - relocate_kernel | ||
| 82 | |||