diff options
Diffstat (limited to 'arch/c6x/lib/divu.S')
| -rw-r--r-- | arch/c6x/lib/divu.S | 98 |
1 files changed, 98 insertions, 0 deletions
diff --git a/arch/c6x/lib/divu.S b/arch/c6x/lib/divu.S new file mode 100644 index 000000000000..64af3c006dd3 --- /dev/null +++ b/arch/c6x/lib/divu.S | |||
| @@ -0,0 +1,98 @@ | |||
| 1 | ;; Copyright 2010 Free Software Foundation, Inc. | ||
| 2 | ;; Contributed by Bernd Schmidt <bernds@codesourcery.com>. | ||
| 3 | ;; | ||
| 4 | ;; This program is free software; you can redistribute it and/or modify | ||
| 5 | ;; it under the terms of the GNU General Public License as published by | ||
| 6 | ;; the Free Software Foundation; either version 2 of the License, or | ||
| 7 | ;; (at your option) any later version. | ||
| 8 | ;; | ||
| 9 | ;; This program is distributed in the hope that it will be useful, | ||
| 10 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of | ||
| 11 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | ||
| 12 | ;; GNU General Public License for more details. | ||
| 13 | ;; | ||
| 14 | ;; You should have received a copy of the GNU General Public License | ||
| 15 | ;; along with this program; if not, write to the Free Software | ||
| 16 | ;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. | ||
| 17 | |||
| 18 | #include <linux/linkage.h> | ||
| 19 | |||
| 20 | ;; ABI considerations for the divide functions | ||
| 21 | ;; The following registers are call-used: | ||
| 22 | ;; __c6xabi_divi A0,A1,A2,A4,A6,B0,B1,B2,B4,B5 | ||
| 23 | ;; __c6xabi_divu A0,A1,A2,A4,A6,B0,B1,B2,B4 | ||
| 24 | ;; __c6xabi_remi A1,A2,A4,A5,A6,B0,B1,B2,B4 | ||
| 25 | ;; __c6xabi_remu A1,A4,A5,A7,B0,B1,B2,B4 | ||
| 26 | ;; | ||
| 27 | ;; In our implementation, divu and remu are leaf functions, | ||
| 28 | ;; while both divi and remi call into divu. | ||
| 29 | ;; A0 is not clobbered by any of the functions. | ||
| 30 | ;; divu does not clobber B2 either, which is taken advantage of | ||
| 31 | ;; in remi. | ||
| 32 | ;; divi uses B5 to hold the original return address during | ||
| 33 | ;; the call to divu. | ||
| 34 | ;; remi uses B2 and A5 to hold the input values during the | ||
| 35 | ;; call to divu. It stores B3 in on the stack. | ||
| 36 | |||
| 37 | .text | ||
| 38 | ENTRY(__c6xabi_divu) | ||
| 39 | ;; We use a series of up to 31 subc instructions. First, we find | ||
| 40 | ;; out how many leading zero bits there are in the divisor. This | ||
| 41 | ;; gives us both a shift count for aligning (shifting) the divisor | ||
| 42 | ;; to the, and the number of times we have to execute subc. | ||
| 43 | |||
| 44 | ;; At the end, we have both the remainder and most of the quotient | ||
| 45 | ;; in A4. The top bit of the quotient is computed first and is | ||
| 46 | ;; placed in A2. | ||
| 47 | |||
| 48 | ;; Return immediately if the dividend is zero. | ||
| 49 | mv .s2x A4, B1 | ||
| 50 | [B1] lmbd .l2 1, B4, B1 | ||
| 51 | || [!B1] b .s2 B3 ; RETURN A | ||
| 52 | || [!B1] mvk .d2 1, B4 | ||
| 53 | mv .l1x B1, A6 | ||
| 54 | || shl .s2 B4, B1, B4 | ||
| 55 | |||
| 56 | ;; The loop performs a maximum of 28 steps, so we do the | ||
| 57 | ;; first 3 here. | ||
| 58 | cmpltu .l1x A4, B4, A2 | ||
| 59 | [!A2] sub .l1x A4, B4, A4 | ||
| 60 | || shru .s2 B4, 1, B4 | ||
| 61 | || xor .s1 1, A2, A2 | ||
| 62 | |||
| 63 | shl .s1 A2, 31, A2 | ||
| 64 | || [B1] subc .l1x A4,B4,A4 | ||
| 65 | || [B1] add .s2 -1, B1, B1 | ||
| 66 | [B1] subc .l1x A4,B4,A4 | ||
| 67 | || [B1] add .s2 -1, B1, B1 | ||
| 68 | |||
| 69 | ;; RETURN A may happen here (note: must happen before the next branch) | ||
| 70 | _divu_loop: | ||
| 71 | cmpgt .l2 B1, 7, B0 | ||
| 72 | || [B1] subc .l1x A4,B4,A4 | ||
| 73 | || [B1] add .s2 -1, B1, B1 | ||
| 74 | [B1] subc .l1x A4,B4,A4 | ||
| 75 | || [B1] add .s2 -1, B1, B1 | ||
| 76 | || [B0] b .s1 _divu_loop | ||
| 77 | [B1] subc .l1x A4,B4,A4 | ||
| 78 | || [B1] add .s2 -1, B1, B1 | ||
| 79 | [B1] subc .l1x A4,B4,A4 | ||
| 80 | || [B1] add .s2 -1, B1, B1 | ||
| 81 | [B1] subc .l1x A4,B4,A4 | ||
| 82 | || [B1] add .s2 -1, B1, B1 | ||
| 83 | [B1] subc .l1x A4,B4,A4 | ||
| 84 | || [B1] add .s2 -1, B1, B1 | ||
| 85 | [B1] subc .l1x A4,B4,A4 | ||
| 86 | || [B1] add .s2 -1, B1, B1 | ||
| 87 | ;; loop backwards branch happens here | ||
| 88 | |||
| 89 | ret .s2 B3 | ||
| 90 | || mvk .s1 32, A1 | ||
| 91 | sub .l1 A1, A6, A6 | ||
| 92 | shl .s1 A4, A6, A4 | ||
| 93 | shru .s1 A4, 1, A4 | ||
| 94 | || sub .l1 A6, 1, A6 | ||
| 95 | or .l1 A2, A4, A4 | ||
| 96 | shru .s1 A4, A6, A4 | ||
| 97 | nop | ||
| 98 | ENDPROC(__c6xabi_divu) | ||