sparc,sparc64: unify kernel/

o Move all files from sparc64/kernel/ to sparc/kernel
  - rename as appropriate
o Update sparc/Makefile to the changes
o Update sparc/kernel/Makefile to include the sparc64 files

NOTE: This commit changes link order on sparc64!

Link order had to change for either of sparc32 and sparc64.
And assuming sparc64 see more testing than sparc32 change link
order on sparc64 where issues will be caught faster.

Signed-off-by: Sam Ravnborg <sam@ravnborg.org>
Signed-off-by: David S. Miller <davem@davemloft.net>

1 files changed, 63 insertions, 0 deletions

diff --git a/arch/sparc/kernel/helpers.S b/arch/sparc/kernel/helpers.S
new file mode 100644
index 000000000000..314dd0c9fc5b
--- /dev/null
+++ b/arch/sparc/kernel/helpers.S
@@ -0,0 +1,63 @@
+        .align  32
+        .globl  __flushw_user
+        .type   __flushw_user,#function
+__flushw_user:
+        rdpr    %otherwin, %g1
+        brz,pn  %g1, 2f
+         clr    %g2
+1:      save    %sp, -128, %sp
+        rdpr    %otherwin, %g1
+        brnz,pt %g1, 1b
+         add    %g2, 1, %g2
+1:      sub     %g2, 1, %g2
+        brnz,pt %g2, 1b
+         restore %g0, %g0, %g0
+2:      retl
+         nop
+        .size   __flushw_user,.-__flushw_user
+
+        /* Flush %fp and %i7 to the stack for all register
+         * windows active inside of the cpu.  This allows
+         * show_stack_trace() to avoid using an expensive
+         * 'flushw'.
+         */
+        .globl          stack_trace_flush
+        .type           stack_trace_flush,#function
+stack_trace_flush:
+        rdpr            %pstate, %o0
+        wrpr            %o0, PSTATE_IE, %pstate
+
+        rdpr            %cwp, %g1
+        rdpr            %canrestore, %g2
+        sub             %g1, 1, %g3
+
+1:      brz,pn          %g2, 2f
+         sub            %g2, 1, %g2
+        wrpr            %g3, %cwp
+        stx             %fp, [%sp + STACK_BIAS + RW_V9_I6]
+        stx             %i7, [%sp + STACK_BIAS + RW_V9_I7]
+        ba,pt           %xcc, 1b
+         sub            %g3, 1, %g3
+
+2:      wrpr            %g1, %cwp
+        wrpr            %o0, %pstate
+
+        retl
+         nop
+        .size           stack_trace_flush,.-stack_trace_flush
+
+#ifdef CONFIG_SMP
+        .globl          hard_smp_processor_id
+        .type           hard_smp_processor_id,#function
+hard_smp_processor_id:
+#endif
+        .globl          real_hard_smp_processor_id
+        .type           real_hard_smp_processor_id,#function
+real_hard_smp_processor_id:
+        __GET_CPUID(%o0)
+        retl
+         nop
+#ifdef CONFIG_SMP
+        .size           hard_smp_processor_id,.-hard_smp_processor_id
+#endif
+        .size           real_hard_smp_processor_id,.-real_hard_smp_processor_id