Linux-2.6.12-rc2v2.6.12-rc2

Initial git repository build. I'm not bothering with the full history,
even though we have it. We can create a separate "historical" git
archive of that later if we want to, and in the meantime it's about
3.2GB when imported into git - space that would just make the early
git days unnecessarily complicated, when we don't have a lot of good
infrastructure for it.

Let it rip!

1 files changed, 46 insertions, 0 deletions

diff --git a/arch/sh/lib/div64.S b/arch/sh/lib/div64.S
new file mode 100644
index 000000000000..eefc275d64a7
--- /dev/null
+++ b/arch/sh/lib/div64.S
@@ -0,0 +1,46 @@
+/*      
+ * unsigned long long __xdiv64_32(unsigned long long n, unsigned long d); 
+ */
+
+#include <linux/linkage.h>
+
+.text
+ENTRY(__xdiv64_32)
+#ifdef  __LITTLE_ENDIAN__
+        mov     r4, r0
+        mov     r5, r1
+#else
+        mov     r4, r1
+        mov     r5, r0
+#endif
+        cmp/hs  r6, r1
+        bf.s    1f
+         mov    #0, r2
+
+        mov     r1, r2
+        mov     #0, r3
+        div0u
+        .rept   32
+        rotcl   r2
+        div1    r6, r3
+        .endr
+        rotcl   r2
+        mul.l   r6, r2
+        sts     macl, r3
+        sub     r3, r1
+1:
+        div0u
+        .rept   32
+        rotcl   r0
+        div1    r6, r1
+        .endr
+#ifdef  __LITTLE_ENDIAN__
+        mov     r2, r1
+        rts
+         rotcl  r0
+#else
+        rotcl   r0
+        mov     r0, r1
+        rts
+         mov    r2, r0
+#endif