Merge branch 'for-linus' of git://git390.marist.edu/pub/scm/linux-2.6

* 'for-linus' of git://git390.marist.edu/pub/scm/linux-2.6: (35 commits)
  [S390] time: remove unused code
  [S390] zcore: Add prefix registers to dump header
  [S390] correct vdso version string
  [S390] add support for compressed kernels
  [S390] Define new s390 ELF note sections in elf.h
  [S390] codepage conversion of kernel parameter line
  [S390] seq_file: convert drivers/s390/
  [S390] add z9-ec/z10 instruction to kernel disassembler
  [S390] dasd: correct offline processing
  [S390] dasd: fix refcounting.
  [S390] dasd: fix online/offline race
  [S390] use kprobes_built_in() in mm/fault code
  [S390] bug: use relative pointers in bug table entries
  [S390] Cleanup struct _lowcore usage and defines.
  [S390] free_initmem: reduce code duplication
  [S390] Replace ENOTSUPP usage with EOPNOTSUPP
  [S390] spinlock: check virtual cpu running status
  [S390] sysinfo: fix SYSIB 3,2,2 structure
  [S390] add MACHINE_IS_LPAR flag
  [S390] qdio: optimize cache line usage of struct qdio_irq
  ...

1 files changed, 48 insertions, 0 deletions

diff --git a/arch/s390/boot/compressed/head64.S b/arch/s390/boot/compressed/head64.S
new file mode 100644
index 000000000000..2982cb140550
--- /dev/null
+++ b/arch/s390/boot/compressed/head64.S
@@ -0,0 +1,48 @@
+/*
+ * Startup glue code to uncompress the kernel
+ *
+ * Copyright IBM Corp. 2010
+ *
+ *   Author(s): Martin Schwidefsky <schwidefsky@de.ibm.com>
+ */
+
+#include <linux/init.h>
+#include <asm/asm-offsets.h>
+#include <asm/thread_info.h>
+#include <asm/page.h>
+#include "sizes.h"
+
+__HEAD
+        .globl  startup_continue
+startup_continue:
+        basr    %r13,0                  # get base
+.LPG1:
+        # setup stack
+        lg      %r15,.Lstack-.LPG1(%r13)
+        aghi    %r15,-160
+        brasl   %r14,decompress_kernel
+        # setup registers for memory mover & branch to target
+        lgr     %r4,%r2
+        lg      %r2,.Loffset-.LPG1(%r13)
+        la      %r4,0(%r2,%r4)
+        lg      %r3,.Lmvsize-.LPG1(%r13)
+        lgr     %r5,%r3
+        # move the memory mover someplace safe
+        la      %r1,0x200
+        mvc     0(mover_end-mover,%r1),mover-.LPG1(%r13)
+        # decompress image is started at 0x11000
+        lgr     %r6,%r2
+        br      %r1
+mover:
+        mvcle   %r2,%r4,0
+        jo      mover
+        br      %r6
+mover_end:
+
+        .align  8
+.Lstack:
+        .quad   0x8000 + (1<<(PAGE_SHIFT+THREAD_ORDER))
+.Loffset:
+        .quad   0x11000
+.Lmvsize:
+        .quad   SZ__bss_start