powerpc: Fix various syscall/signal/swapcontext bugs

A careful reading of the recent changes to the system call entry/exit
paths revealed several problems, plus some things that could be
simplified and improved:

* 32-bit wasn't testing the _TIF_NOERROR bit in the syscall fast exit
  path, so it was only doing anything with it once it saw some other
  bit being set.  In other words, the noerror behaviour would apply to
  the next system call where we had to reschedule or deliver a signal,
  which is not necessarily the current system call.

* 32-bit wasn't doing the call to ptrace_notify in the syscall exit
  path when the _TIF_SINGLESTEP bit was set.

* _TIF_RESTOREALL was in both _TIF_USER_WORK_MASK and
  _TIF_PERSYSCALL_MASK, which is odd since _TIF_RESTOREALL is only set
  by system calls.  I took it out of _TIF_USER_WORK_MASK.

* On 64-bit, _TIF_RESTOREALL wasn't causing the non-volatile registers
  to be restored (unless perhaps a signal was delivered or the syscall
  was traced or single-stepped).  Thus the non-volatile registers
  weren't restored on exit from a signal handler.  We probably got
  away with it mostly because signal handlers written in C wouldn't
  alter the non-volatile registers.

* On 32-bit I simplified the code and made it more like 64-bit by
  making the syscall exit path jump to ret_from_except to handle
  preemption and signal delivery.

* 32-bit was calling do_signal unnecessarily when _TIF_RESTOREALL was
  set - but I think because of that 32-bit was actually restoring the
  non-volatile registers on exit from a signal handler.

* I changed the order of enabling interrupts and saving the
  non-volatile registers before calling do_syscall_trace_leave; now we
  enable interrupts first.

Signed-off-by: Paul Mackerras <paulus@samba.org>

2 files changed, 24 insertions, 72 deletions

diff --git a/arch/ppc/kernel/asm-offsets.c b/arch/ppc/kernel/asm-offsets.c
index 7964bf660e92..77e4dc780f8c 100644
--- a/arch/ppc/kernel/asm-offsets.c
+++ b/arch/ppc/kernel/asm-offsets.c
@@ -131,7 +131,6 @@ main(void)
         DEFINE(CPU_SPEC_FEATURES, offsetof(struct cpu_spec, cpu_features));
         DEFINE(CPU_SPEC_SETUP, offsetof(struct cpu_spec, cpu_setup));
 
-        DEFINE(TI_SIGFRAME, offsetof(struct thread_info, nvgprs_frame));
         DEFINE(TI_TASK, offsetof(struct thread_info, task));
         DEFINE(TI_EXECDOMAIN, offsetof(struct thread_info, exec_domain));
         DEFINE(TI_FLAGS, offsetof(struct thread_info, flags));
diff --git a/arch/ppc/kernel/entry.S b/arch/ppc/kernel/entry.S
index a48b950722a1..3a2815978488 100644
--- a/arch/ppc/kernel/entry.S
+++ b/arch/ppc/kernel/entry.S
@@ -227,7 +227,7 @@ ret_from_syscall:
         MTMSRD(r10)
         lwz     r9,TI_FLAGS(r12)
         li      r8,-_LAST_ERRNO
-        andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SIGPENDING|_TIF_NEED_RESCHED|_TIF_RESTOREALL)
+        andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
         bne-    syscall_exit_work
         cmplw   0,r3,r8
         blt+    syscall_exit_cont
@@ -287,8 +287,10 @@ syscall_dotrace:
 
 syscall_exit_work:
         andi.   r0,r9,_TIF_RESTOREALL
-        bne-    2f
-        cmplw   0,r3,r8
+        beq+    0f
+        REST_NVGPRS(r1)
+        b       2f
+0:      cmplw   0,r3,r8
         blt+    1f
         andi.   r0,r9,_TIF_NOERROR
         bne-    1f
@@ -302,9 +304,7 @@ syscall_exit_work:
 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
         beq     4f
 
-        /* Clear per-syscall TIF flags if any are set, but _leave_
-        _TIF_SAVE_NVGPRS set in r9 since we haven't dealt with that
-        yet.  */
+        /* Clear per-syscall TIF flags if any are set.  */
 
         li      r11,_TIF_PERSYSCALL_MASK
         addi    r12,r12,TI_FLAGS
@@ -318,8 +318,13 @@ syscall_exit_work:
         subi    r12,r12,TI_FLAGS
         
 4:      /* Anything which requires enabling interrupts? */
-        andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_SAVE_NVGPRS)
-        beq     7f
+        andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
+        beq     ret_from_except
+
+        /* Re-enable interrupts */
+        ori     r10,r10,MSR_EE
+        SYNC
+        MTMSRD(r10)
 
         /* Save NVGPRS if they're not saved already */
         lwz     r4,TRAP(r1)
@@ -328,71 +333,11 @@ syscall_exit_work:
         SAVE_NVGPRS(r1)
         li      r4,0xc00
         stw     r4,TRAP(r1)
-
-        /* Re-enable interrupts */
-5:      ori     r10,r10,MSR_EE
-        SYNC
-        MTMSRD(r10)
-
-        andi.   r0,r9,_TIF_SAVE_NVGPRS
-        bne     save_user_nvgprs
-
-save_user_nvgprs_cont:
-        andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
-        beq     7f
-
+5:
         addi    r3,r1,STACK_FRAME_OVERHEAD
         bl      do_syscall_trace_leave
-        REST_NVGPRS(r1)
-
-6:      lwz     r3,GPR3(r1)
-        LOAD_MSR_KERNEL(r10,MSR_KERNEL) /* doesn't include MSR_EE */
-        SYNC
-        MTMSRD(r10)             /* disable interrupts again */
-        rlwinm  r12,r1,0,0,18   /* current_thread_info() */
-        lwz     r9,TI_FLAGS(r12)
-7:
-        andi.   r0,r9,_TIF_NEED_RESCHED
-        bne     8f
-        lwz     r5,_MSR(r1)
-        andi.   r5,r5,MSR_PR
-        beq     ret_from_except
-        andi.   r0,r9,_TIF_SIGPENDING
-        beq     ret_from_except
-        b       do_user_signal
-8:
-        ori     r10,r10,MSR_EE
-        SYNC
-        MTMSRD(r10)             /* re-enable interrupts */
-        bl      schedule
-        b       6b
-
-save_user_nvgprs:
-        lwz     r8,TI_SIGFRAME(r12)
-
-.macro savewords start, end
-  1:    stw \start,4*(\start)(r8)
-        .section __ex_table,"a"
-        .align  2
-        .long   1b,save_user_nvgprs_fault
-        .previous
-        .if \end - \start
-        savewords "(\start+1)",\end
-        .endif
-.endm   
-        savewords 14,31
-        b       save_user_nvgprs_cont
-
-        
-save_user_nvgprs_fault:
-        li      r3,11           /* SIGSEGV */
-        lwz     r4,TI_TASK(r12)
-        bl      force_sigsegv
+        b       ret_from_except_full
 
-        rlwinm  r12,r1,0,0,18   /* current_thread_info() */
-        lwz     r9,TI_FLAGS(r12)
-        b       save_user_nvgprs_cont
-        
 #ifdef SHOW_SYSCALLS
 do_show_syscall:
 #ifdef SHOW_SYSCALLS_TASK
@@ -490,6 +435,14 @@ ppc_clone:
         stw     r0,TRAP(r1)             /* register set saved */
         b       sys_clone
 
+        .globl  ppc_swapcontext
+ppc_swapcontext:
+        SAVE_NVGPRS(r1)
+        lwz     r0,TRAP(r1)
+        rlwinm  r0,r0,0,0,30            /* clear LSB to indicate full */
+        stw     r0,TRAP(r1)             /* register set saved */
+        b       sys_swapcontext
+
 /*
  * Top-level page fault handling.
  * This is in assembler because if do_page_fault tells us that
@@ -683,7 +636,7 @@ user_exc_return:		/* r10 contains MSR_KERNEL here */
         /* Check current_thread_info()->flags */
         rlwinm  r9,r1,0,0,18
         lwz     r9,TI_FLAGS(r9)
-        andi.   r0,r9,(_TIF_SIGPENDING|_TIF_NEED_RESCHED|_TIF_RESTOREALL)
+        andi.   r0,r9,(_TIF_SIGPENDING|_TIF_RESTORE_SIGMASK|_TIF_NEED_RESCHED)
         bne     do_work
 
 restore_user: