parisc: implement irq stacks

Default kernel stack size on parisc is 16k.  During tests we found that the
kernel stack can easily grow beyond 13k, which leaves 3k left for irq
processing.

This patch adds the possibility to activate an additional stack of 16k per CPU
which is being used during irq processing.  This implementation does not yet
uses this irq stack for the irq bh handler.

The assembler code for call_on_stack was heavily cleaned up by John
David Anglin.

CC: John David Anglin <dave.anglin@bell.net>
Signed-off-by: Helge Deller <deller@gmx.de>

1 files changed, 41 insertions, 0 deletions

diff --git a/arch/parisc/kernel/entry.S b/arch/parisc/kernel/entry.S
index 3f3326d876f7..4bb96ad9b0b1 100644
--- a/arch/parisc/kernel/entry.S
+++ b/arch/parisc/kernel/entry.S
@@ -2010,6 +2010,47 @@ ftrace_stub:
 ENDPROC(return_to_handler)
 #endif  /* CONFIG_FUNCTION_TRACER */
 
+#ifdef CONFIG_IRQSTACKS
+/* void call_on_stack(unsigned long param1, void *func,
+                      unsigned long new_stack) */
+ENTRY(call_on_stack)
+        copy    %sp, %r1
+
+        /* Regarding the HPPA calling conventions for function pointers,
+           we assume the PIC register is not changed across call.  For
+           CONFIG_64BIT, the argument pointer is left to point at the
+           argument region allocated for the call to call_on_stack. */
+# ifdef CONFIG_64BIT
+        /* Switch to new stack.  We allocate two 128 byte frames.  */
+        ldo     256(%arg2), %sp
+        /* Save previous stack pointer and return pointer in frame marker */
+        STREG   %rp, -144(%sp)
+        /* Calls always use function descriptor */
+        LDREG   16(%arg1), %arg1
+        bve,l   (%arg1), %rp
+        STREG   %r1, -136(%sp)
+        LDREG   -144(%sp), %rp
+        bve     (%rp)
+        LDREG   -136(%sp), %sp
+# else
+        /* Switch to new stack.  We allocate two 64 byte frames.  */
+        ldo     128(%arg2), %sp
+        /* Save previous stack pointer and return pointer in frame marker */
+        STREG   %r1, -68(%sp)
+        STREG   %rp, -84(%sp)
+        /* Calls use function descriptor if PLABEL bit is set */
+        bb,>=,n %arg1, 30, 1f
+        depwi   0,31,2, %arg1
+        LDREG   0(%arg1), %arg1
+1:
+        be,l    0(%sr4,%arg1), %sr0, %r31
+        copy    %r31, %rp
+        LDREG   -84(%sp), %rp
+        bv      (%rp)
+        LDREG   -68(%sp), %sp
+# endif /* CONFIG_64BIT */
+ENDPROC(call_on_stack)
+#endif /* CONFIG_IRQSTACKS */
 
 get_register:
         /*