i386: prepare shared kernel/trampoline.S

Signed-off-by: Thomas Gleixner <tglx@linutronix.de>
Signed-off-by: Ingo Molnar <mingo@elte.hu>

1 files changed, 0 insertions, 85 deletions

diff --git a/arch/i386/kernel/trampoline.S b/arch/i386/kernel/trampoline.S
deleted file mode 100644
index f62815f8d06a..000000000000
--- a/arch/i386/kernel/trampoline.S
+++ /dev/null
@@ -1,85 +0,0 @@
-/*
- *
- *      Trampoline.S    Derived from Setup.S by Linus Torvalds
- *
- *      4 Jan 1997 Michael Chastain: changed to gnu as.
- *
- *      This is only used for booting secondary CPUs in SMP machine
- *
- *      Entry: CS:IP point to the start of our code, we are 
- *      in real mode with no stack, but the rest of the 
- *      trampoline page to make our stack and everything else
- *      is a mystery.
- *
- *      In fact we don't actually need a stack so we don't
- *      set one up.
- *
- *      We jump into the boot/compressed/head.S code. So you'd
- *      better be running a compressed kernel image or you
- *      won't get very far.
- *
- *      On entry to trampoline_data, the processor is in real mode
- *      with 16-bit addressing and 16-bit data.  CS has some value
- *      and IP is zero.  Thus, data addresses need to be absolute
- *      (no relocation) and are taken with regard to r_base.
- *
- *      If you work on this file, check the object module with
- *      objdump --reloc to make sure there are no relocation
- *      entries except for:
- *
- *      TYPE              VALUE
- *      R_386_32          startup_32_smp
- *      R_386_32          boot_gdt
- */
-
-#include <linux/linkage.h>
-#include <asm/segment.h>
-#include <asm/page.h>
-
-.data
-
-/* We can free up trampoline after bootup if cpu hotplug is not supported. */
-#ifndef CONFIG_HOTPLUG_CPU
-.section ".init.data","aw",@progbits
-#endif
-
-.code16
-
-ENTRY(trampoline_data)
-r_base = .
-        wbinvd                  # Needed for NUMA-Q should be harmless for others
-        mov     %cs, %ax        # Code and data in the same place
-        mov     %ax, %ds
-
-        cli                     # We should be safe anyway
-
-        movl    $0xA5A5A5A5, trampoline_data - r_base
-                                # write marker for master knows we're running
-
-        /* GDT tables in non default location kernel can be beyond 16MB and
-         * lgdt will not be able to load the address as in real mode default
-         * operand size is 16bit. Use lgdtl instead to force operand size
-         * to 32 bit.
-         */
-
-        lidtl   boot_idt_descr - r_base # load idt with 0, 0
-        lgdtl   boot_gdt_descr - r_base # load gdt with whatever is appropriate
-
-        xor     %ax, %ax
-        inc     %ax             # protected mode (PE) bit
-        lmsw    %ax             # into protected mode
-        # flush prefetch and jump to startup_32_smp in arch/i386/kernel/head.S
-        ljmpl   $__BOOT_CS, $(startup_32_smp-__PAGE_OFFSET)
-
-        # These need to be in the same 64K segment as the above;
-        # hence we don't use the boot_gdt_descr defined in head.S
-boot_gdt_descr:
-        .word   __BOOT_DS + 7                   # gdt limit
-        .long   boot_gdt - __PAGE_OFFSET        # gdt base
-
-boot_idt_descr:
-        .word   0                               # idt limit = 0
-        .long   0                               # idt base = 0L
-
-.globl trampoline_end
-trampoline_end: